Amelia's Wristpocket Magnet

[Squishmellow3]

A relatively cheap magnet spell (0.5 dust per item + 0.5 dust base cost if you have something in your wristpocket already) which uses the wristpocket to bring all nearby items to you. (Requires Hexical, for the wristpocket.)

Code: Select all

{
	Pocket Reflection //check if user has empty wristpocket
	Nullary Reflection
	Equality Distillation
	{
		False Reflection //at end of hex, item does not need retrieved
	}
	{
		Mind's Reflection //put item 16 blocks above the user. at end of hex, item does need retrieved
		Compass' Purification
		Vector Reflection. +Y
		Numerical Reflection: 16
		Multiplicative Distillation
		Additive Distillation
		Gemini Decomposition
		Sleight
		Entity Purification: Item
		True Reflection
	}
	Augur's Exaltation //get all items within 15 blocks of the user (any more would select whatever was previously in the wristpocket)
	Hermes' Gambit
	Mind's Reflection
	Compass' Purification
	Numerical Reflection: 15
	Zone Distillation: Item 
	{
		Sleight //bring every item in the list to yourself
		Mind's Reflection
		Compass' Purification
		Sleight
	}
	Jester's Gambit //run it, and discard of the empty list
	Thoth's Gambit
	Bookkeeper's Gambit: v 
	{
		Sleight
	}
	{
	}
	Augur's Exaltation
	Hermes' Gambit //restore old wristpocket state
}

[gwhitlock74]

Squishmellow3, the bit where it puts the old wristpocket item back at the end is the clever part, to be fair. Ive lost count of the times id have wiped my own pocket with something like this and then spent ten minutes wondering where my stuff went. Only thing id add is that 15 blocks is plenty, ive no doubt it would hoover up half the loose items in my base in one go, not ideal, that.